home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
CU Amiga Super CD-ROM 6
/
CU Amiga Magazine's Super CD-ROM 06 (1996)(EMAP Images)(GB)(Track 1 of 4)[!][issue 1997-01].iso
/
cucd
/
graphics
/
cybergraphx
/
cyberavi
/
install
< prev
next >
Wrap
Text File
|
1996-10-23
|
3KB
|
157 lines
;
; $VER: CyberAVI installation 1.0 (8.10.96)
;
; Copyright (c) 1996 Thore Böckelmann
;
;****************************************************************************
;
; English texts
;
(set #bad-kick "You must have AmigaOS 3.0 (V39) or newer to be able to use CyberAVI.")
(set #bad-cpu "You must have at least an MC68020 to use CyberAVI.")
;****************************************************************************
;
; Setup
;
(complete 0)
(if (< (/ (getversion) 65536) 39)
(abort #bad-kick)
)
(if (patmatch "68000|68010" (database "cpu"))
(abort #bad-cpu)
)
(set @default-dest "SYS:")
(set @libs-dest "LIBS:")
;****************************************************************************
;
; Welcome
;
(welcome)
(complete 10)
;****************************************************************************
;
; Setup directory
;
(set #destdir
(askdir
(prompt "Please select where to install CyberAVI\nA directory 'CyberAVI' will be created automatically")
(help @askdir-help)
(default @default-dest)
(newpath)
)
)
(set #libsdir
(askdir
(prompt "Please select where to install necessary libraries")
(help @askdir-help)
(default @libs-dest)
)
)
(set @default-dest (tackon #destdir "CyberAVI"))
(set @libs-dest #libsdir)
(complete 20)
(makedir @default-dest
(prompt "Creating directory 'CyberAVI'")
(help @makedir-help)
(infos)
)
(complete 40)
;****************************************************************************
;
; Copy main program
;
(copyfiles
(prompt "Copying CyberAVI...")
(help @copyfiles-help)
(source "CyberAVI")
(dest @default-dest)
(infos)
(confirm)
)
(complete 60)
;****************************************************************************
;
; Copy documentation
;
(copyfiles
(prompt "Copying documentation...")
(help @copyfiles-help)
(source "")
(pattern "#?.(guide|readme)")
(dest @default-dest)
(infos)
(confirm)
)
(complete 80)
;****************************************************************************
;
; Install libraries
;
(copylib
(help @copylib-help)
(prompt "Copying asyncio.library...")
(source "asyncio.library")
(dest @libs-dest)
(confirm)
)
;****************************************************************************
;
; Install GUI
;
(if (askbool
(prompt "\n\nDo you want to install the Argue interface for CyberAVI?\n(You need to have Argue installed!)")
(help "You will have to get argue13.lha and argue13a.lha from Aminet to use this graphical user interface.\n\nArgue is ©1996 by Thorsten Stocksmeier")
)
(
(copyfiles
(prompt "Copying interface for CyberAVI...")
(help @copyfiles-help)
(source "CyberAVI GUI")
(dest @default-dest)
(infos)
(confirm)
)
(tooltype
(dest (tackon @default-dest "CyberAVI GUI"))
(settooltype "COMMAND" (tackon @default-dest "CyberAVI"))
)
)
)
;****************************************************************************
;
; Exit
;
(complete 100)
(exit)